Navigae SPARQL End Point

Principes

Accès à Navigae GeoSPARQL

Le SPARQL Endpoint permet d'interroger les données structurées au format RDF présentes sur la plateforme Navigae
Accéder à Navigae GeoSPARQL

Accès distant au SPARQL Endpoint

Pour accéder au SPARQL endpoint Navigae depuis un autre environnement à distance, l'URL du repository est la suivante : https://www.navigae.fr/graphdb/repositories/Navigae

L'ontologie Navigae

L'ontologie Navigae est une représentation des connaissances présentes sur la plateforme Navigae et construites sur le modèle de données de RDF

GeoSPARQL

Les données de Navigae sont représentées selon le modèle GeoSPARQL.
GeoSPARQL est un standard de représentation et d'interrogation de données géospatiales liées pour le Web sémantique et défini par l'Open Geospatial Consortium (OGC).
Ce qui suit est un diagramme simplifié des classes GeoSPARQL Feature et Geometry, ainsi que de certaines de leurs propriétés :

Exemples de requêtes SPARQL

Récupérer les données de Navigae

Écrire une requête simple pour remonter l'ensemble des cartes ou des photos présentes :

PREFIX nav: <https://www.navigae.fr/ontology#>
SELECT * WHERE {
  { ?s a nav:GeolocatedData. }
}  
LIMIT 10

Tester

Récupérer les objets les plus proches

Remonte les 3 objets les plus proches de la photo d'identifiant https://hdl.handle.net/20.500.12187/508c8f3a-b820-36ed-bc65-9a07cff4d8c6 localisée en 44.270778656006, -71.30451965332 :

PREFIX uom: <http://www.opengis.net/def/uom/OGC/1.0/>
PREFIX nav: <https://www.navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT ?f ?fWKT ?cWKT ?d
WHERE {
    <https://hdl.handle.net/20.500.12187/508c8f3a-b820-36ed-bc65-9a07cff4d8c6> nav:hasPointGeometry ?cGeom .
    ?cGeom geo:asWKT ?cWKT .
    ?f nav:hasPointGeometry ?fGeom .
    ?fGeom geo:asWKT ?fWKT .
    FILTER (?fGeom != ?cGeom)
    BIND(geof:distance(?cWKT, ?fWKT, uom:metre) AS ?d)
}
ORDER BY ASC(?d)
LIMIT 3

Tester

Récupérer les points inclus dans une zone prédéfinie

Remonte l'ensemble des points situées dans une zone dessinée aux alentours de Bamako.

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT ?f ?fGeom ?fWKT
WHERE {
    ?f nav:hasPointGeometry ?fGeom .
    ?fGeom geo:asWKT ?fWKT .
    FILTER (geof:sfWithin(?fWKT, '''
        <http://www.opengis.net/def/crs/OGC/1.3/CRS84>
            Polygon ((-9.08 13.84,
                      -9.08 11.84, -7.08 11.84,
                      -7.08 13.84, -9.08 13.84))
'''^^geo:wktLiteral))
}

Tester

Récupérer les polygones inclus dans une zone prédéfinie

Remonte l'ensemble des polygones situées dans une zone dessinée aux alentours de Bamako.

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT ?f ?fGeom ?fWKT
WHERE {
    ?f nav:hasPolygonGeometry ?fGeom .
    ?fGeom geo:asWKT ?fWKT .
    FILTER (geof:sfWithin(?fWKT, '''
        <http://www.opengis.net/def/crs/OGC/1.3/CRS84>
            Polygon ((-9.08 13.84,
                      -9.08 11.84, -7.08 11.84,
                      -7.08 13.84, -9.08 13.84))
'''^^geo:wktLiteral))
}

Tester

Construire une zone calculée sur les coordonnées des objets

Calcule la bounding box minimale entre cet Atlas de la Réunion et cette photo de la Plaine de l'Imbo (Burundi) :

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>
PREFIX uom: <http://www.opengis.net/def/uom/OGC/1.0/>

SELECT *
WHERE {
    <https://hdl.handle.net/20.500.12187/7e1a948f-47ce-369a-90c0-89c8052c831d> nav:hasPointGeometry ?aGeom .
    ?aGeom geo:asWKT ?aWKT .
    <https://hdl.handle.net/20.500.12187/dd58afad-710d-3c27-8f43-c1ebe9b7d8b4> nav:hasPointGeometry ?bGeom .
    ?bGeom geo:asWKT ?bWKT .
    BIND (geof:envelope(geof:union(?aWKT, ?bWKT)) AS ?envelope) 
}

Tester

Détecter les zones de chevauchement

Identifier l'ensemble des objets qui chevauchent la carte du département d'Antoquia en Colombie :

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT ?f ?fWKT ?a
WHERE {
    <https://hdl.handle.net/20.500.12187/3c58789b-f3b9-3af4-90b5-60831d1b6ef6> nav:hasPolygonGeometry ?aGeom .
    ?aGeom geo:asWKT ?aWKT.
    ?f nav:hasPolygonGeometry ?fGeom .
    ?fGeom geo:asWKT ?fWKT.
    FILTER (geof:sfOverlaps(?fWKT, ?aWKT)).
}

Tester

Détecter les zones distinctes

Identifier 2 objets géométriques couvrant la même zone sans se chevaucher :

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT *
WHERE {
    ?a nav:hasPolygonGeometry ?aGeom .
    ?aGeom geo:asWKT ?aWKT .
    ?b nav:hasPolygonGeometry ?bGeom .
    ?bGeom geo:asWKT ?bWKT .
    FILTER (geof:sfWithin(?aWKT, '''
        <http://www.opengis.net/def/crs/OGC/1.3/CRS84>
            Polygon ((-9.08 13.84,
                      -9.08 11.84, -7.08 11.84,
                      -7.08 13.84, -9.08 13.84))
'''^^geo:wktLiteral))
  FILTER (geof:sfWithin(?bWKT, '''
        <http://www.opengis.net/def/crs/OGC/1.3/CRS84>
            Polygon ((-9.08 13.84,
                      -9.08 11.84, -7.08 11.84,
                      -7.08 13.84, -9.08 13.84))
'''^^geo:wktLiteral))
   FILTER(?a != ?b)
   FILTER (geof:ehDisjoint(?aWKT, ?bWKT))
}
LIMIT 1

Tester