Navigae SPARQL End Point

Principes

GeoSPARQL Navigae Access

The SPARQL endpoint allows you to query structured data in RDF format from Navigae platform.
Access to GeoSPARQL Navigae

Remote Access to SPARQL Endpoint

To access the SPARQL endpoint Navigae from another remote environment, the repository URL is: https://www.navigae.fr/graphdb/repositories/Navigae

The Navigae ontology

This ontology is a representation of data stored on the Navigae platform and built according to the RDF data model.

GeoSPARQL

Data model is designed on the GeoSPARQL represention
GeoSPARQL GeoSPARQL is a standard for representing and querying geospatial linked data for the Semantic Web from the Open Geospatial Consortium (OGC).
The following picture is a simplified diagram of the GeoSPARQL classes Feature and Geometry, as well as some of their properties :

SPARQL requests samples

Retrieve data from Navigae

Write a simple query to put together all the maps or photographs available :

PREFIX nav: <https://www.navigae.fr/ontology#>
SELECT * WHERE {
  { ?s a nav:GeolocatedData. }
}  
LIMIT 10

Test

Get the nearest objects

Find 3 objects the closest to the photography of identifier https://hdl.handle.net/20.500.12187/508c8f3a-b820-36ed-bc65-9a07cff4d8c6 located in 44.270778656006, -71.30451965332 :

PREFIX uom: <http://www.opengis.net/def/uom/OGC/1.0/>
PREFIX nav: <https://www.navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT ?f ?fWKT ?cWKT ?d
WHERE {
    <https://hdl.handle.net/20.500.12187/508c8f3a-b820-36ed-bc65-9a07cff4d8c6> nav:hasPointGeometry ?cGeom .
    ?cGeom geo:asWKT ?cWKT .
    ?f nav:hasPointGeometry ?fGeom .
    ?fGeom geo:asWKT ?fWKT .
    FILTER (?fGeom != ?cGeom)
    BIND(geof:distance(?cWKT, ?fWKT, uom:metre) AS ?d)
}
ORDER BY ASC(?d)
LIMIT 3

Test

Compute points included in a predefined area

Find all the points located in an area drawn around Bamako.

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT ?f ?fGeom ?fWKT
WHERE {
    ?f nav:hasPointGeometry ?fGeom .
    ?fGeom geo:asWKT ?fWKT .
    FILTER (geof:sfWithin(?fWKT, '''
        <http://www.opengis.net/def/crs/OGC/1.3/CRS84>
            Polygon ((-9.08 13.84,
                      -9.08 11.84, -7.08 11.84,
                      -7.08 13.84, -9.08 13.84))
'''^^geo:wktLiteral))
}

Test

Compute polygons included in a predefined area

Find all the polygons located in an area drawn around Bamako.

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT ?f ?fGeom ?fWKT
WHERE {
    ?f nav:hasPolygonGeometry ?fGeom .
    ?fGeom geo:asWKT ?fWKT .
    FILTER (geof:sfWithin(?fWKT, '''
        <http://www.opengis.net/def/crs/OGC/1.3/CRS84>
            Polygon ((-9.08 13.84,
                      -9.08 11.84, -7.08 11.84,
                      -7.08 13.84, -9.08 13.84))
'''^^geo:wktLiteral))
}

Test

Construct a calculated area based on geolocation

Compute the minimum bounding box minimale between this Atlas of The Reunion and this photo of the Plain of Imbo (Burundi) :

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>
PREFIX uom: <http://www.opengis.net/def/uom/OGC/1.0/>

SELECT *
WHERE {
    <https://hdl.handle.net/20.500.12187/7e1a948f-47ce-369a-90c0-89c8052c831d> nav:hasPointGeometry ?aGeom .
    ?aGeom geo:asWKT ?aWKT .
    <https://hdl.handle.net/20.500.12187/dd58afad-710d-3c27-8f43-c1ebe9b7d8b4> nav:hasPointGeometry ?bGeom .
    ?bGeom geo:asWKT ?bWKT .
    BIND (geof:envelope(geof:union(?aWKT, ?bWKT)) AS ?envelope) 
}

Test

Detect overlap areas

Identify all items that overlap the Antoquia department map from Colombia :

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT ?f ?fWKT ?a
WHERE {
    <https://hdl.handle.net/20.500.12187/3c58789b-f3b9-3af4-90b5-60831d1b6ef6> nav:hasPolygonGeometry ?aGeom .
    ?aGeom geo:asWKT ?aWKT.
    ?f nav:hasPolygonGeometry ?fGeom .
    ?fGeom geo:asWKT ?fWKT.
    FILTER (geof:sfOverlaps(?fWKT, ?aWKT)).
}

Test

Detect distinct areas

Identify two geometric objects covering the same area without overlapping :

PREFIX nav: <http://navigae.fr/ontology#>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>

SELECT *
WHERE {
    ?a nav:hasPolygonGeometry ?aGeom .
    ?aGeom geo:asWKT ?aWKT .
    ?b nav:hasPolygonGeometry ?bGeom .
    ?bGeom geo:asWKT ?bWKT .
    FILTER (geof:sfWithin(?aWKT, '''
        <http://www.opengis.net/def/crs/OGC/1.3/CRS84>
            Polygon ((-9.08 13.84,
                      -9.08 11.84, -7.08 11.84,
                      -7.08 13.84, -9.08 13.84))
'''^^geo:wktLiteral))
  FILTER (geof:sfWithin(?bWKT, '''
        <http://www.opengis.net/def/crs/OGC/1.3/CRS84>
            Polygon ((-9.08 13.84,
                      -9.08 11.84, -7.08 11.84,
                      -7.08 13.84, -9.08 13.84))
'''^^geo:wktLiteral))
   FILTER(?a != ?b)
   FILTER (geof:ehDisjoint(?aWKT, ?bWKT))
}
LIMIT 1

Test